pkgname=keepassgo-git
pkgver=@PKGVER@
pkgrel=1
pkgdesc='KeePass-compatible password manager written in Go'
arch=('x86_64' 'aarch64')
url='https://git.julianfamily.org/joejulian/keepassgo'
license=('custom')
depends=(
  'glibc'
  'hicolor-icon-theme'
  'libx11'
  'libxcursor'
  'libxfixes'
  'libxkbcommon'
  'libxkbcommon-x11'
  'mesa'
  'wayland'
)
makedepends=(
  'git'
  'go'
  'pkgconf'
)
provides=('keepassgo')
conflicts=('keepassgo')
source=('git+https://git.julianfamily.org/joejulian/keepassgo.git')
sha256sums=('SKIP')

_repo_dir() {
  printf '%s\n' "@REPO_DIR@"
}

pkgver() {
  cd "$(_repo_dir)"
  printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$(_repo_dir)"
  export CGO_ENABLED=1
  export GOFLAGS="-trimpath"
  local app_version
  app_version="$(git describe --tags --always --dirty)"
  go build -ldflags "-X git.julianfamily.org/keepassgo/internal/appui.appVersion=${app_version}" -o keepassgo ./cmd/keepassgo
}

package() {
  cd "$(_repo_dir)"

  install -Dm755 keepassgo "${pkgdir}/usr/bin/keepassgo"
  install -Dm644 internal/assets/keepassgo-icon.png \
    "${pkgdir}/usr/share/icons/hicolor/512x512/apps/keepassgo.png"
  install -Dm644 internal/assets/keepassgo-icon.svg \
    "${pkgdir}/usr/share/icons/hicolor/scalable/apps/keepassgo.svg"
  install -Dm644 packaging/archlinux/keepassgo-git/keepassgo.desktop \
    "${pkgdir}/usr/share/applications/keepassgo.desktop"
  install -Dm644 README.md \
    "${pkgdir}/usr/share/licenses/${pkgname}/README.md"
}